set verbose off
clear

open dbnomics

# ================================================================
string countrycode = "GRC" #for OECD
print countrycode
string countrycode1 = "EL" #for Eurostat
print countrycode1
# ================================================================

string seriescode1 = "Eurostat/namq_10_gdp/Q.CLV15_MEUR.SCA.B1GQ."~countrycode1
print seriescode1
data @seriescode1 --name=rgdpEL

string seriescode = "OECD/QNA/"~countrycode~".B1_GA.LNBQRSA.Q"
print seriescode
data @seriescode --name=@countrycode

#CPI
data Eurostat/ei_cphi_m/M.HICP2015.NSA.CP-HI00.EL --name=CPIEL --compact=average
CPIELd = deseas(CPIEL)
# Quarterly annualized inflation for Greece
series infl = 400*log(CPIELd/CPIELd(-1))

# Quarterly annualized growth rate for Greece
series dy = 400*log(rgdpEL/rgdpEL(-1))

genr time

#AR(1) model for inflation
AR1 <- ols infl const infl(-1)

#Phillips curve ARDL model
ARDL <- ols infl const infl(-1) dy(0 to -1)
modtest --autocorr 2
residuals = $uhat
corrgm residuals 12 --plot=display

# OUT-OF-SAMPLE-FORECAST
# NEXT 3 years
dataset addobs 12
smpl 2024:3 ;
dy = 2.94863 #Scenario growth equals mean for the period 2022:01 - 2024:02

smpl 1995:01 2024:2
ARDL <- ols infl const infl(-1) dy(0 to -1)
fcast 2024:3 2027:2 --plot=display

AR1 <- ols infl const infl(-1)
fcast 2024:3 2027:2 --plot=display