set verbose off
clear

set seed 1635945385

scalar T = 500
nulldata T --preserve
setobs 1 1 --special-time-series

series ut = normal(0,1) # Gaussian white noise
/*
ΠΡΟΣΟΧΗ στην επιλογή τιμών για τα φ1 και φ2 (phi1, phi2).
Για στασιμότητα θα πρέπει ....
Για μη-στασιμότητα I(1) θέστε φ1+φ2=1
*/
scalar m = 0 #μ
scalar phi1 = 1.25 #φ1
scalar phi2 = -0.45 #φ2
scalar a = m*(1-phi1-phi2) #α

smpl 1 2
series yt = m

smpl 3 T
yt = a + phi1*yt(-1) + phi2*yt(-2) + ut
setinfo yt --graph-name="y(t) = α + φ1*y(t-1) + φ2*y(t-2) + u(t)"

smpl full

string gtitle = sprintf("α=%4.2f , φ1=%4.2f και φ2=%4.2f", a, phi1, phi2)
gnuplot yt --time-series --with-lines --output=display { set title "@gtitle"; }

corrgm yt 16 --plot=display

/*
Συγκρίνετε τη συνάρτηση μερικής αυτοσυσχέτισης PACF από παραπάνω με τους
εκτιμημένους συντελεστές φ2 από τις παρακάτω παλινδρομήσεις.
Θα δείτε ότι είναι ίσες.
Για παράδειγμα, η PACF στην υστέρηση k=2 δίνει -0.3742.
Το ίδιο και η εκτίμηση του φ2 στην δεύτερη παλινδρόμηση παρακάτω,
του φ3 στην τρίτη παλινδρόμηση παρακάτω κ.ο.κ 
*/

loop i = 1..16
    ols yt 0 yt(-1 to -i) --quiet
    printf "Εκτίμηση φ%d= %6.4f\n",i,$coeff[i+1]
endloop